TeamViewer 9 unattended Install

Ich habe gerade einen Nachfolger für das Script aus dem Beitrag Teamviewer 8 Host Silent Install geschrieben. Dieses Script ist allerdings auf die normale, vollständige Version ausgerichtet – eine Variante für TeamViewer 9 Host wird noch folgen eine Variante für TeamViewer 9 Host gibt es unter TeamViewer 9 Host unattended Install. Es ermöglicht es TeamViewer 9 unattended zu installieren, was eigentlich ja dem MSI-Paket vorbehalten ist – welches leider ausschließlich mit der (sehr kostspieligen) Corporate-Lizenz verfügbar ist.

Update #1, 3. Mai 2014

Mir ist gerade aufgefallen, das wenn das kompilierte Script von einem anderen Ort aufgerufen wurde (z.B durch ein anderes Programm wie mein Basixx Installer) es seine Konfigurationsdatei nicht finden konnte. Dies ist nun behoben, sowohl im Download als auch im Sourcelisting.

Mögliche und nötige Anpassungen für die TeamViewer 9 unattended install

TeamViewer 9 unattended

• Das Verbindungs-Passwort, sowie die TeamViewer-Konto Daten, werden aus der INI-Datei „tv9_full.conf“ geladen. Dort gibt es auch eine Option um die Verzögerung zwischen simulierten Tastendrücken anzupassen (Beispiel-INI siehe Download)
• Zeile 68-70 → Hier werden, zuvor unter Optionen > Erweiterte Einstellungen exportierte, TeamViewer Einstellungen importiert. Entweder muss dieser Abschnitt auskommentiert werden, oder ein entsprechender Export erstellt werden.
• Das Skript erwartet einen deutschen Installer, wenn die erwarteten Texte angepasst werden kann es aber auch für andere Sprachversionen genutzt werden.

Hier das Skript, wieder mit AutoIt realisiert:

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=..\update.ico
#AutoIt3Wrapper_Outfile=tv9_full.exe
#AutoIt3Wrapper_Compression=4
#AutoIt3Wrapper_Res_Comment=TeamViewer 9 unattented installscript
#AutoIt3Wrapper_Res_Description=This script automates the TeamViewer 9 setup
#AutoIt3Wrapper_Res_Fileversion=1.1.0.0
#AutoIt3Wrapper_Res_LegalCopyright=© 2014 
#AutoIt3Wrapper_Res_Language=1031
#AutoIt3Wrapper_Res_requestedExecutionLevel=requireAdministrator
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

$verTag = "9"
$strTrayTitle = "TeamViewer " & $verTag & " Auto-Install"

$wTitle = "TeamViewer " & $verTag & " Installation"
$wTitle2 = "Unbeaufsichtigter Zugriff"
$wTitle3 = "Unbeaufsichtigter Zugriff - Schritt 1 von 2"
$wTitle4 = "Unbeaufsichtigter Zugriff - Schritt 2 von 2"
$strUser = IniRead(@ScriptDir & "\tv9_full.conf", "Setup", "AccountUsername", "Du hast vergessen deinen Benutzernamen einzugeben!")
$strPass = IniRead(@ScriptDir & "\tv9_full.conf", "Setup", "AccountPassword", "")
$strPassword = IniRead(@ScriptDir & "\tv9_full.conf", "Setup", "ConnectPassword", "")
Opt("SendKeyDelay", Int(IniRead(@ScriptDir & "\tv9_full.conf", "Setup", "SendKeyDelay", "250")) )

; Install
TrayTip($strTrayTitle, "Warte auf Setup...", 0, 1)
WinWait($wTitle, "Installieren, um später aus der Ferne auf diesen Computer zuzugreifen")
TrayTip($strTrayTitle, "Konfiguriere Installation...", 0, 1)
WinActivate($wTitle)
ControlClick($wTitle, "", "[CLASS:Button; INSTANCE:5]") ; Installieren, um später aus der Ferne auf diesen Computer zuzugreifen check
ControlClick($wTitle, "", "[CLASS:Button; INSTANCE:8]") ; privat / nicht-kommerziell check
ControlClick($wTitle, "", "[CLASS:Button; INSTANCE:10]") ; Erweiterte Einstellungen check
ControlClick($wTitle, "", "[CLASS:Button; INSTANCE:2]") ; Stimme zu - weiter
WinWait($wTitle, "Erweiterte Einstellungen")
ControlClick($wTitle, "", "[CLASS:Button; INSTANCE:2]") ; Fertig stellen
WinWaitClose($wTitle)

; Install done - adding to list
TrayTip($strTrayTitle, "Installation abgeschlossen, füge Computer zur Support-Liste hinzu...", 0, 1)
WinWait($wTitle2, "Unbeaufsichtigten Zugriff einrichten")
WinActivate($wTitle2)
ControlClick($wTitle2, "", "[CLASS:Button; INSTANCE:2]") ; Weiter
WinWait($wTitle3, "Kennwort")
WinActivate($wTitle3)
ControlSend($wTitle3, "", "[CLASS:Edit; INSTANCE:2]", $strPassword) ; Passwort 1
ControlSend($wTitle3, "", "[CLASS:Edit; INSTANCE:3]", $strPassword) ; Passwort confirm
ControlClick($wTitle3, "", "[CLASS:Button; INSTANCE:2]") ; Weiter
WinWait($wTitle4, "Ich habe bereits ein TeamViewer Konto")
WinActivate($wTitle4)
ControlClick($wTitle4, "", "[CLASS:Button; INSTANCE:2]") ; Ich habe bereits ein TeamViewer Konto
ControlSend($wTitle4, "", "[CLASS:Edit; INSTANCE:2]", $strUser) ; User
ControlSend($wTitle4, "", "[CLASS:Edit; INSTANCE:3]", $strPass) ; Pass
ControlClick($wTitle4, "", "[CLASS:Button; INSTANCE:6]") ; Weiter
WinWait($wTitle2, "Abschluss des Assistenten")
WinActivate($wTitle2)
ControlClick($wTitle2, "", "[CLASS:Button; INSTANCE:7]") ; Fertigstellen
WinWaitClose($wTitle2)
TrayTip($strTrayTitle, "", 0, 1)

; Close initial launch
WinWait("TeamViewer", "Bitte geben Sie die ID Ihres Partners ein, um dessen Computer fernzusteuern.")
WinActivate("TeamViewer", "Bitte geben Sie die ID Ihres Partners ein, um dessen Computer fernzusteuern.")
WinClose("TeamViewer", "Bitte geben Sie die ID Ihres Partners ein, um dessen Computer fernzusteuern.")

TrayTip($strTrayTitle, "Alles erledigt, setze noch ein paar Einstellungen...", 0, 1)

; Import configuration
RunWait(@ComSpec & " /c net stop TeamViewer9", @ScriptDir)
RunWait(@ComSpec & " /c ""regedit.exe /s tv9_full.reg""", @ScriptDir)
RunWait(@ComSpec & " /c net start TeamViewer9", @ScriptDir)

TrayTip($strTrayTitle, "Alles fertig - beende mich.", 15, 1)
Exit

Natürlich macht es nur kompiliert Sinn.

Download TeamViewer 9 unattended script

In diesem Archiv sind der Quelltext, die kompilierte Executable und eine Beispielkonfiguration. Vor Benutzung muss die Datei „tv9_full.conf“ mit den eigenen Daten gefüllt werden. Um die TeamViewer 9 unattented Installation zu starten muss dann einfach das TeamViewer 9 Setup, gefolgt vom Script gestartet werden. Da das Script aber sowie auf die Setup-Fenster wartet spielt die Reihenfolge eigentlich keine Rolle, es kann genauso gut zuerst das Script und dann erst das Setup gestartet werden.